++++++++++>>>++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++[<<+>+>-]<----------------------------<++++++++++++++++++++++++++++>>,[------------------------------------------------[-[-[-[-[-[-[-[-[-[--------[-[-[-[-[-[<<<.>>>[-]>]<[<....>>]>]<[<...>.>]>]<[<..>.<.>>]>]<[<..>..>]>]<[<.>.<..>>]>]<[<.>.<.>.>]>]<[<.>..<.>>]>]<[<.>...>]>]<[.<...>>]>]<[.<..>.>]>]<[.<.>.<.>>]>]<[.<.>..>]>]<[..<..>>]>]<[..<.>.>]>]<[...<.>>]>]<[....>],]
Attempt This Online!
The input can be separated by every character with a value bigger than 'F'.
The working section looks like this:
| '\n' | 'X' | ' ' | {input character} | 0 (used for stopping loops) |
prepare the initial state
++++++++++ newline
prepare space and X
>>> ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ [<<+>+>-]
< ---------------------------- space
< ++++++++++++++++++++++++++++ X
Go to start position and read char
>>,
[
subtract '0'
------------------------------------------------
[ if !0
-[ if !1
-[ if !2
-[ if !3
-[ if !4
-[ if !5
-[ if !6
-[ if !7
-[ if !8
-[ if !9
subtract difference between 'A' and '9'
-------
-[ if !A
-[ if !B
-[ if !C
-[ if !D
-[ if !E
-[ if !F
print newline
<<<.>>>
clear input character
[-]>
]
<[ print 'F' <....>> ]>
]
<[ print 'E' <...>.> ]>
]
<[ print 'D' <..>.<.>> ]>
]
<[ print 'C' <..>..> ]>
]
<[ print 'B' <.>.<..>> ]>
]
<[ print 'A' <.>.<.>.> ]>
]
<[ print '9' <.>..<.>> ]>
]
<[ print '8' <.>...> ]>
]
<[ print '7' .<...>> ]>
]
<[ print '6' .<..>.> ]>
]
<[ print '5' .<.>.<.>> ]>
]
<[ print '4' .<.>..> ]>
]
<[ print '3' ..<..>> ]>
]
<[ print '2' ..<.>.> ]>
]
<[ print '1' ...<.>> ]>
]
<[ print '0' ....> ]
read next input
,
]
```
